프로그래밍

3204,

153/161

바볼이

아 제발..ㅠ흑흑

http://www.hackerschool.org/HS_Boards/zboard.php?id=QNA_programming&no=2143 [복사]

요즘 제가 커널 만드는걸 공부하고 있는데요..
중간에 막힌것이 있어요..

음..

일단 소스는 밑에 꺼에요.

<BOOT.ASM>

[org 0]
[bits 16]

jmp 0x07c0:bootstart

bootstart:

mov ax,cs
mov ds,ax

read:

mov ax,0x1000
mov es,ax
mov bx,0
mov ah,2
mov al,1
mov ch,0
mov cl,2
mov dh,0
mov dl,0
int 13h

jnc next
jc read

next:

cli

lgdt[gdtr]

mov eax,cr0
or eax,1
mov cr0,eax

jmp $+2
nop
nop

mov bx,SysDataSelector
mov ds,bx
mov es,bx
mov fs,bx
mov gs,bx
mov ss,bx

jmp dword SysCodeSelector:0x10000

gdtr:
dw gdt_end - gdt - 1
dd gdt+0x7c00

gdt:

;Null Descriptor
dd 0x00000000
dd 0x00000000

SysCodeSelector equ 0x8
dd 0x0000ffff
dd 0x00cf9a00

SysDataSelector equ 0x10
dd 0x0000ffff
dd 0x00cf9200

VideoSelector equ 0x18
dd 0x8000ffff
dd 0x0040920b

gdt_end:

times 510-($-$$) db 0
;MBR
dw 0xaa55

<KERNEL.ASM>

;Video text color
%define BLACK 0x00
%define BLUE 0x01
%define GREEN 0x02
%define SKY 0x03
%define RED 0x04
%define PURPLE 0x05
%define BROWN 0x06
%define WHITE 0x07

[org 0x10000]
[bits 32]
;GLOBAL DESCRIPTOR
SysCodeSelector equ 0x8
SysDataSelector equ 0x10
VideoSelector equ 0x18

;START OF KERNEL
start:
;INITIALIZING
mov bx,SysDataSelector
mov ds,bx
mov es,bx
mov fs,bx
mov gs,bx
mov ss,bx
lea esp,[start]

mov edi,0
lea esi, [msgNOTICEpmmode]
call print

jmp $

msgNOTICEpmmode db "Entered in Protected mode.", 0

;PRINT FUNCTION
print:
push eax
push es
mov ax, VideoSelector
mov es,ax
print_loop:
mov al,byte[esi]
mov byte[es:di],al
inc edi
mov byte[es:di], SKY
inc esi
inc edi
or al,al
jz print_end
jmp print_loop
print_end:
pop es
pop eax
ret
;END OF PRINT

저기 위에 boot.asm 부분에서 오류가 나는데..

그 오류가 뭐냐하면..무려 리부팅입니다 ㅠ

VMware 가 말하길 stack fault 라고는 하는데... 널 디스크립터도 잘 해줬거든요?? 근데 왜 이러는 걸까요 ㅠ..

Hit : 3134 Date : 2009/10/02 06:12


commio	원인이야... 찾아내고 수정했습니다만... 어떻게 설명을 해야할지 모르겠네요 ㅠ_ㅠ... 커널 제작쪽은 저도 그렇게 높은 수준이 아니라... 조금이나마 도움을 주고자 수정을하고 설명을 해드릴려고 했는데... 너무 제 방식대로 되어버린거같아서요 ㅠ_ㅠ 대충이나마 제가 알아낸 정보를 알려드릴께요... ㅎㅎ	2009/10/04
commio	jmp $+2 nop nop mov bx,SysDataSelector mov ds,bx mov es,bx mov fs,bx mov gs,bx mov ss,bx jmp dword SysCodeSelector:0x10000	2009/10/04
commio	위에 부분이 제가 추정하는 발생 에러 원인이고요, jmp $+2 nop nop 이 부분을 보니... 어떤 어셈블러를 쓰시나요..? 어셈블러의 종류와 버젼에 따라서 jmp $+2 가 번역되는 기계어가 달라지기 때문에 안전하지않습니다. jmp here nop nop here: 이런식으로 해주시는게 버젼에 관계없이 안전하게 동작합니다.	2009/10/04
commio	그리고 중복되는 코드가 미친듯이 많은데... 제가 위에서 말한.. mov bx,SysDataSelector mov ds,bx mov es,bx mov fs,bx mov gs,bx mov ss,bx 이부분도 점프해서 어차피 하는 코드인데... 그냥 제거해주시는게 낫고...	2009/10/04
commio	read: mov ax,0x1000 mov es,ax mov bx,0 mov ah,2 mov al,1 mov ch,0 mov cl,2 mov dh,0 mov dl,0 int 13h jnc next jc read next:	2009/10/04
commio	이부분 역시 jnc next 를 삭제하고 jc read만 있어도 충분히 원하는 대로 동작합니다. 아무리 더미커널이라지만... 커널이라는 녀석은 최대한 가볍고 빨라야하는데... 이렇게 쓸데 없는 중복코드... 또한 서브루틴으로 만들어 두신 print 역시 치명저인 문제를 가지고 있습니다. 속도를 제외하고도 원하는 출력 이상의 결과물을 내어 놓을수 있습니다. 그리고... 커널제작을 발을 넣으신거라면... 디셈블링은 필수 입니다. 제가 위에서말한 jmp $+2 도 디셈해서 발견했습니다... 그때만 생각하면 눈물이 뚝뚝 흐르네요ㅠ_ㅠ 몇칠동안 아우... 무튼 힘내시고요!! 커널 제작하려는 사람들이 별로 없어서 그런지 자료공유라던지 그런게 없네요 -0 -ㅋ 무튼 화이팅!! ㅋ	2009/10/04